home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS / PRO088A.dsk / INSTAL2.bas < prev    next >
BASIC Source File  |  2012-02-16  |  7KB  |  161 lines
  1. 10  REM  YO YO DUCK DIAGNOSTIC PROGRAM
  2. 20  REM  SPECIAL INSTALLER'S EDITION
  3. 22 D$ =  CHR$(4)
  4. 30  IF  PEEK(64448) = 224  AND  PEEK(65055) = 96  THEN COMP$ = "IIE Enhanced":NL = 1
  5. 32  IF  PEEK(64448) = 224  AND  PEEK(65055) = 173  THEN COMP$ = "IIGS":NL = 2
  6. 34  IF  PEEK(64448) = 0  THEN COMP$ = "IIC":NL = 3
  7. 40  PRINT D$;"OPEN NUMCOMP,L20"
  8. 42  PRINT D$;"READ  NUMCOMP,R";NL
  9. 44  INPUT NC
  10. 46  PRINT D$;"WRITE NUMCOMP,R";NL
  11. 50 NC = NC +1
  12. 54  PRINT NC
  13. 56  PRINT D$;"CLOSE NUMCOMP"
  14. 110  HOME 
  15. 120  VTAB 8: PRINT "TESTING FOR COMPUTER-DRIVE CONNECTION"
  16. 130  PRINT : PRINT  TAB( 5);"TYPE 'Q' TO SKIP C.D.CONNECTION"
  17. 140  VTAB 15: PRINT  TAB( 5);"SLOT NUMBER: 5"
  18. 150  VTAB 15: HTAB 18: GET S$: PRINT S$
  19. 160  IF S$ = "Q"  OR S$ = "q"  THEN 470
  20. 170  IF S$ =  CHR$(13)  THEN SN = 5: GOTO 200
  21. 180  IF S$ <"5"  OR S$ >"7"  THEN  PRINT  CHR$(7): GOTO 140
  22. 190 SN =  VAL(S$)
  23. 200  VTAB 17: PRINT  TAB( 4);"DRIVE NUMBER: 2"
  24. 210  VTAB 17: HTAB 18: GET DN$: PRINT DN$
  25. 220  IF DN$ =  CHR$(13)  THEN DN = 2: GOTO 260
  26. 230  IF DN$ = "Q"  OR DN$ = "q"  THEN 470
  27. 240  IF DN$ <"1"  OR DN$ >"2"  THEN  PRINT  CHR$(7): GOTO 200
  28. 250 DN =  VAL(DN$)
  29. 260  HOME 
  30. 270  VTAB 8: PRINT  TAB( 6);"PLACE YO YO DIAGNOSTIC DISK": PRINT 
  31. 280  PRINT  TAB( 10);"INTO SLOT ";SN;" DRIVE ";DN
  32. 290  PRINT : PRINT  TAB( 7);"PRESS RETURN TO CONTINUE: ";
  33. 300  GET P$: PRINT P$
  34. 310  PRINT  CHR$(4);"CAT,S";SN;",D";DN
  35. 320  PRINT : PRINT : PRINT 
  36. 330  VTAB 22: PRINT  TAB( 6);"PRESS RETURN TO CONTINUE: ";: GET A$: PRINT A$
  37. 340  HOME 
  38. 350  VTAB 8: HTAB 6
  39. 360  PRINT "PLACE YO YO DIAGNOSTIC DISK"
  40. 370  PRINT : PRINT  TAB( 10);"INTO SLOT 5"
  41. 380  VTAB 10: HTAB 20: GET S$: PRINT S$
  42. 390  IF S$ =  CHR$(13)  THEN SN = 5: GOTO 420
  43. 400  IF S$ <"5"  OR S$ >"7"  THEN  PRINT  CHR$(7): GOTO 380
  44. 410 SN =  VAL(S$)
  45. 420  VTAB 10: HTAB 22: PRINT "DRIVE 1"
  46. 430  VTAB 10: HTAB 28: GET DN$: PRINT DN$
  47. 440  IF DN$ =  CHR$(13)  THEN DN = 1: GOTO 470
  48. 450  IF DN$ <"1"  OR DN$ >"2"  THEN  PRINT  CHR$(7): GOTO 430
  49. 460 DN =  VAL(DN$)
  50. 470  REM  MONITOR TESTS
  51. 500 U = 9:D = 3:E =  -16384:F =  -16368:G =  -16287:H =  -16286:Z = 127
  52. 510  POKE 768,173: POKE 769,48: POKE 770,192: POKE 771,136: POKE 772,208: POKE 773,4: POKE 774,198: POKE 775,7
  53. 520  POKE 776,240: POKE 777,8: POKE 778,202: POKE 779,208: POKE 780,246: POKE 781,166: POKE 782,6: POKE 783,76: POKE 784,0: POKE 785,03: POKE 786,96
  54. 525  TEXT : HOME : PRINT : POKE F,0
  55. 530  GOSUB 532
  56. 531  GOTO 550
  57. 532  GR : FOR I = 0 TO 31: COLOR= I/2: VLIN 0,39 AT I +3: NEXT I
  58. 534  COLOR= 5: VLIN 0,39 AT 2: VLIN 0,39 AT 35: HLIN 2,35 AT 0: HLIN 2,35 AT 39
  59. 536  FOR I = 1 TO  LEN(A$)
  60. 538  HTAB 2 *I +2: PRINT  MID$ (A$,I,1);
  61. 540  NEXT I: RETURN 
  62. 550 A$ = "BMDPDGMLBOGPLYAW": GOSUB 536: PRINT 
  63. 560 A$ = "LGBUGRBBRRRIGEQI": GOSUB 536: PRINT 
  64. 570 A$ = "ATLRRELLWNENRLUT": GOSUB 536: PRINT 
  65. 580 A$ = "KAUPNYUUNGYKNOAE": GOSUB 536
  66. 590  GET A$: PRINT A$
  67. 600  REM  CROSSHATCH TEST
  68. 610  HGR2 : HCOLOR= 7
  69. 620  FOR Y = 0 TO 180  STEP 18: HPLOT 0,Y TO 279,Y: NEXT Y
  70. 630  FOR X = 0 TO 252  STEP 28: HPLOT X,0 TO X,179: NEXT X
  71. 640  HPLOT 279,0 TO 279,179
  72. 650  GET A$: PRINT A$
  73. 720  REM  
  74. 730 M1$ = "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890"
  75. 740 M2$ = "abcdefghijklmnopqrstuvwxyz"
  76. 750  TEXT : NORMAL : HOME 
  77. 760  PRINT "THIS IS NORMAL": PRINT : PRINT M1$: PRINT M2$
  78. 770  PRINT : PRINT : FLASH 
  79. 780  PRINT "THIS IS FLASH": PRINT : PRINT M1$
  80. 790  NORMAL : PRINT : PRINT : INVERSE 
  81. 800  PRINT "THIS IS INVERSE": PRINT : PRINT M1$
  82. 810  NORMAL 
  83. 820  VTAB 22: PRINT  TAB( 7);"PRESS A KEY TO CONTINUE: ";: GET A$: PRINT A$
  84. 830  PRINT  CHR$(4);"PR#3"
  85. 840  PRINT : PRINT : PRINT : PRINT 
  86. 850  PRINT "THIS IS NORMAL": POKE 1403,5: PRINT M1$: PRINT M2$
  87. 860  PRINT : PRINT 
  88. 870  PRINT "This is MouseText"
  89. 880  PRINT  CHR$(27); CHR$(15);
  90. 890  POKE 1403,5
  91. 900  PRINT "@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_"
  92. 910  PRINT  CHR$(24): REM  TURN OFF ALT CHAR SET  
  93. 920  PRINT : PRINT "THIS IS INVERSE"
  94. 930  POKE 1403,5: PRINT M1$
  95. 940  POKE 1403,5: PRINT M2$
  96. 950  PRINT  CHR$(14): REM  NORMAL
  97. 960  FOR I = 1 TO 1200: NEXT I
  98. 970  PRINT  CHR$(17);: FOR J = 1 TO 2250: NEXT J: PRINT  CHR$(18)
  99. 980  PRINT : PRINT : PRINT : PRINT : PRINT 
  100. 990  PRINT "PRESS RETURN TO CONTINUE: ";
  101. 1000  CALL  -756
  102. 1010  PRINT  CHR$(12); CHR$(21)
  103. 1050  HOME 
  104. 1060  VTAB 8: PRINT "IS THERE A PRINTER ATTACTED?  (Y/N) "
  105. 1070  VTAB 8: HTAB 36: GET A$: PRINT A$
  106. 1080  IF A$ = "N"  OR A$ = "n"  THEN  END 
  107. 1090  IF A$ < >"Y"  AND A$ < >"y"  THEN  PRINT  CHR$(7): GOTO 1070
  108. 1110 EX$ = "THIS IS EXTENDED (9 CPI)
  109. 1120 P$ = "THIS IS PICA (12 CPI)"
  110. 1130 E$ = "THIS IS ELITE (10 CPI)"
  111. 1140 CO$ = "THIS IS CONDENSED (15 CPI)
  112. 1150 M$ = "THIS IS MICRON (17 CPI)"
  113. 1160 CM$ = "THIS IS COMPRESSED (17.6 CPI)
  114. 1170 EM$ = "THIS IS THE EMPHASIZED MODE"
  115. 1180 NM$ = "THIS IS THE NEAR LETTER QUALITY MODE"
  116. 1190 N1$ = "     PRINTER TEST FOR:  "
  117. 1200 N2$ = "     MAKE SURE PRINTER IS TURNED ON"
  118. 1210 SB$ = "     PRESS <SPACEBAR> TO CONTINUE: "
  119. 1220 M4$ = "           (314) 837-1200"
  120. 1230 M5$ = "  THE BOTTOM LINE"
  121. 1240 M6$ = "  16 CROSS KEYS SHOPPING CENTER"
  122. 1250 M7$ = "  FLORISSANT  MO  63033"
  123. 1260 M8$ = "   THE                     HELPING YOUR"
  124. 1270 M9$ = "     BOTTOM                 KIDS MAKE"
  125. 1280 MA$ = "         LINE               THE GRADE"
  126. 1290  REM    IMAGEWRITER II BLACK PRINT TEST
  127. 1300  PRINT D$;"PR#1"
  128. 1310  PRINT  CHR$(14): PRINT "IMAGEWRITER GRAPHICS PRINTER DEMO": PRINT  CHR$(15)
  129. 1320  PRINT : PRINT : PRINT "This is a sample APPLE IMAGEWRITER II printout"
  130. 1330  REM  9 CPI
  131. 1340  PRINT  CHR$(27); CHR$(110): PRINT EX$
  132. 1350  PRINT 
  133. 1360  REM  PICA
  134. 1370  PRINT  CHR$(27); CHR$(78): PRINT P$
  135. 1380  REM  ELITE
  136. 1390  PRINT  CHR$(27); CHR$(69): PRINT E$
  137. 1400  REM  CONDENSED
  138. 1410  PRINT  CHR$(27); CHR$(113): PRINT CO$
  139. 1420  REM  MICRON
  140. 1430  PRINT  CHR$(27); CHR$(81): PRINT M$
  141. 1440  REM  BACK TO PICA
  142. 1450  PRINT  CHR$(27); CHR$(34); CHR$(14)
  143. 1460  PRINT "EXPANDED TYPE IS AN OPTION ON ANY PRINT SIZE"
  144. 1470  PRINT  CHR$(15)
  145. 1480  PRINT  CHR$(27); CHR$(78)
  146. 1490  PRINT  CHR$(27); CHR$(88): PRINT "UNDERLINE IS AN OPTION ON ANY PRINT SIZE": PRINT  CHR$(27); CHR$(89)
  147. 1500  PRINT  CHR$(27); CHR$(78): PRINT "This is Pica";
  148. 1510  PRINT  CHR$(27); CHR$(112): PRINT "This is Pica proportional"
  149. 1520  PRINT  CHR$(27); CHR$(69): PRINT "This is Elite";
  150. 1530  PRINT  CHR$(27); CHR$(80): PRINT "This is Elite proportional"
  151. 1540  PRINT  CHR$(27); CHR$(78)
  152. 1550  REM   NLQ 
  153. 1560  PRINT  CHR$(27); CHR$(97); CHR$(50): PRINT NM$
  154. 1570  REM  SUPERSCRIPT - SUBSCRIPT
  155. 1580  PRINT : PRINT "AND THIS IS ";: PRINT  CHR$(27); CHR$(120);: PRINT "SUPERSCRIPT";: PRINT  CHR$(27); CHR$(122);: PRINT " AND THIS IS ";: PRINT  CHR$(27); CHR$(121);: PRINT "SUBSCRIPT"
  156. 1590  REM  NORMAL (SUBSCRIPT OFF, DRAFT, ELITE
  157. 1600  PRINT  CHR$(27); CHR$(122): PRINT  CHR$(27); CHR$(69): PRINT  CHR$(27); CHR$(97); CHR$(49)
  158. 1610  REM  END MESSAGE
  159. 1620  PRINT : PRINT M5$: PRINT M6$: PRINT M7$: PRINT : PRINT M8$: PRINT M9$: PRINT MA$
  160. 1630  PRINT : PRINT M4$
  161. 1640  PRINT  CHR$(4);"PR#0"